Slanted.mp

verbatimtex
%&latex
\documentclass{article}
\newcommand{\fett}{\sffamily\bfseries}
\begin{document}
etex

u:=25;                    % 25 = 25bp = 25 PostScript points = 30/72 in
wi:=10;                   % width  in units u   
he:=7;                    % height in units u
hoehe:=he*u;              % height
breite:=wi*u;             % width
path p[], q[];
picture pic;
transform t, T[];
t:=identity scaled u;

T1:=identity slanted 3/7;
T2:=identity slanted 6/7;
T3:=identity slanted 9/7;

beginfig(1)
  z0=(1,   2) transformed t;
  z1=(2.5, 5) transformed t;
  z2=(1,   5) transformed t;
  z3=(1.5, 4) transformed t;       % label
  
  p0:=z0{1,4}..z1{up}..{down}z2--cycle;
  q0:=(x0, 0)--(x0, hoehe);
  
  for i=1 upto 3:
    p[i]:=p0 transformed T[i];
    q[i]:=q0 transformed T[i];
  endfor

  % --- Grid ---
  for i=0 upto he:
    draw (0, i*u)--(breite, i*u) withcolor .7white;
  endfor
  for j=0 upto wi:
    draw (j*u, 0)--(j*u, hoehe) withcolor .7white;
  endfor
  % --- End Grid ---
  
  draw (0, 0)--(breite, 0)--(breite, hoehe)--(0, hoehe)--cycle;
  
  for i=0 upto 3:    
    fill p[i] withcolor .9white;
    pickup pencircle scaled .5;
    draw q[i] withcolor red;
    pickup pencircle scaled 2;
    draw p[i];
  endfor
  
  label(btex $\mathcal{F}_0$ etex, z3);
  label(btex $\mathcal{F}_1$ etex, z3 transformed T1);
  label(btex $\mathcal{F}_2$ etex, z3 transformed T2);
  label(btex $\mathcal{F}_3$ etex, z3 transformed T3);
  
  pic:=\thelabel.lft(btex 
                       \begin{tabular}{ccl}		       
			 \fett T1 & \fett := & \fett identity slanted 3/7 \\
			 \fett T2 & \fett := & \fett identity slanted 6/7 \\
			 \fett T3 & \fett := & \fett identity slanted 9/7 		         
		       \end{tabular} 
                     etex, (breite-.2u, 1u));
		     
  unfill bbox pic;
  draw pic;
  pickup pencircle scaled .5;
  draw bbox pic;		     
endfig;

end